How To Do a Hot Backup for Windows
Below is the shipped backup.bat script. This script can be executed from the Business Process Scheduler.
By default the backup directory is EBI_HOME\database\backup.
If users want to change the script, it is recommended that they copy the shipped copy. One update would be the target directory, then update the DB_FOLDER_BACKUP variable.
To run the command: Execute backup.bat -online or backup.bat -offline
BACKUP.bat script by EXTOL
@ECHO offREM *************************
REM This batch file performs an backup of EBI's
REM internal storage data.
REM *************************
REM *************************
REM This script should be within ${EBI_INSTALL_DIR}/utils
REM Path construction is relative to this scripts location.
REM *************************
SETLOCAL
if %1 == -online goto :continue
if %1 == -offline goto :continue
echo Usage: backup.bat [-offline | -online]
goto :end
:continue
REM *************************
REM Set EBI Home
REM *************************
SET EBI_HOME=..
REM *************************
REM Set backup folders
REM *************************
SET DB_FOLDER=%EBI_HOME%\database
SET DB_FOLDER_BACKUP=%DB_FOLDER%\backup
SET DB_FOLDER_UTIL=%DB_FOLDER%\utils
REM *************************
REM Backup the database.
REM *************************
cd %DB_FOLDER_UTIL%
call backup_db.bat %1
cd ..\..\utils
SET EBI_HOME=..
REM *************************
REM Create the log file name.
REM *************************
FOR /f "tokens=1-4 delims=/-. " %%G IN ('date /t') DO (call :s_fixdate %%G %%H %%I %%J)
goto :get_time
:s_fixdate
if "%1:~0,1%" GTR "9" shift
FOR /f "skip=1 tokens=2-4 delims=(-)" %%G IN ('echo.^|date') DO (
set %%G=%1&set %%H=%2&set %%I=%3)
goto :eof
:get_time
FOR /f "tokens=*" %%G IN ('time/t') DO set _time=%%G
SET _time=%_time:~0,2%-%_time:~3,2%
SET DATE_TIME=%mm%_%dd%_%yy%@%_time%
SET BACKUP_FOLDER=..\backups
IF NOT EXIST %BACKUP_FOLDER% mkdir %BACKUP_FOLDER%
REM *************************
REM Combine them into a single archive:
REM *************************
SET COMBINED_ARCHIVE_FILE=%BACKUP_FOLDER%\ebi_archive_%DATE_TIME%.jar
REM *************************
REM folders:
REM *************************
SET DB_BACKUP_FOLDER=%DB_FOLDER_BACKUP%\xdb1
SET SM_FOLDER=%EBI_HOME%\ebi
SET LOG_FOLDER=%EBI_HOME%\resources\data\logging
REM *************************
REM Archive the DB backup:
REM *************************
echo Archiving %DB_BACKUP_FOLDER%, %SM_FOLDER%, %LOG_FOLDER% to %COMBINED_ARCHIVE_FILE%
jar -cf %COMBINED_ARCHIVE_FILE% %DB_BACKUP_FOLDER% %SM_FOLDER% %LOG_FOLDER%
:end
ENDLOCAL
By: Sean Hoppe on
